msc:         'msc' '{' entitylist ';' arclist ';' '}' |
             'msc' '{' optionlist ';' entitylist ';' arclist ';' '}'

optionlist:  option | optionlist ',' option

option:      opt '=' string

opt:         'hscale' | 'width' | 'arcgradient'

entitylist:  entity | entitylist ',' entity

entity:      string | entity '[' attrlist ']'

arclist:     arc | arclist ';' arc | arclist ',' arc

arc:         arcrel '[' attrlist ']' | arcrel

arcrel :     string rel_bi string |
             string rel_to string |
             string rel_from string | 
             string rel_to '*' |
             '*' rel_from string | 
             special_arc

attrlist:    attr | attrlist ',' attr

attr:        attrval '=' string

attrval:     'label' | 'url' | 'id' | 'idurl'

rel_bi :     'box' | 'abox' | 'rbox'

rel_to :     '->' | '=>' | '>>' | '=>>' | ':>'

rel_from:    '<-' | '<=' | '<<' | '<<=' | '<:'

special_arc: '...' | '---'

string:      qstr | str

qstr:        '"' [^"]+ '"'

str:         [A-Za-z0-9_]+